HPAVC/HPAVC CD-ROM.iso/pc/LORD2B6.ZIP/PORTTOWN.REF

Text File | 1997-05-18 | 19.7 KB | 1,109 lines

;porttown and surrounding areas

@#JUNKMAN1
@do moveback
@do saybar
Ahh... Comfy chair!  Not like that one bed at Stonepass Lodge...

@#JUNKMAN2
@do moveback
@busy
@show
`r0`c


                     `0"What would ya like to part with, kid?"

@sellmanager

@drawmap
@update

@#FISH
@offmap
@do moveback
@show
`r0`c  `r1  `%The House O' Fish  `r0

  `2People are buying and selling fish all over the place!  You also see
  some nice rods in a corner.  A man introduces himself as `0Smithy`2 and
  asks what you need.

@do `v01 is 1
@do write
`x`x
@choice
Buy something
Sell some fish
Conduct business with Smithy
Leave
@if response is 3 then do
  @begin
  @do `p20 is 2
  @run getquest in quest.ref
  @closescript
  @end

@if response is 1 then do
  @begin
  @do write
`\`\
  @buymanager
  28
  29
  @do goto fish
  @end

@if responce is 2 then do
  @begin
  @label fishsell
  @show
`c  `r1  The market place  `r0

  `2You walk up to a fish bin and show 'em what you got.

  `2You are holding `$$&money`2.

@do write
`x`x
@do `v01 is 1
@choice
<`i29 1 <`i30 1 You have no fish to sell.
>`i29 0 Sell a Salmon for `$$50`%. `2(you have `0`i29`2)
>`i30 0 Sell a Sparking Green Salmon for `$$250`%. `2(you have `0`i30`2)
>`i29 0 <`i30 1 Sell nothing
>`i30 0 <`i29 1 Sell nothing
>`i30 0 >`i29 0 Sell nothing
@if responce is 2 then do
  @begin
  @show
`\`\  `0"Thank you for the fish, s&sir!"

`k
  @do money + 50
  @do `i29 - 1
  @do goto fishsell
  @end
@if responce is 3 then do
  @begin
  @show
`\`\  `0"My god?!? Where did you catch this?!?  Thank you!"

`k
  @do money + 250
  @do `i30 - 1
  @do goto fishsell
  @end

 @do goto fish

 @end

@drawmap
@update

@#man
;Helpfull man in Porttown
@do moveback
@do `p20 random 9 1
@if `p20 is 1 then saybar
`%Guy: `0I hear the longer boat rides are relaxing.
@if `p20 is 2 then saybar
`%Guy: `0I hear there's a shortcut through the Snowy Pass!
@if `p20 is 3 then saybar
`%Guy: `0Watch out for the girls at the inn here...
@if `p20 is 4 then saybar
`%Guy: `0I hear the dark forest is a terrible place.
@if `p20 is 5 then saybar
`%Guy: `0A sailor told me of an undiscovered island once!
@if `p20 is 6 then saybar
`%Guy: `0The Hag's place is the safest place in town!
@if `p20 is 7 then saybar
`%Guy: `0Did you know Mr T. is Great!?
@if `p20 is 8 then saybar
`%Guy: `0On the other two continents I hear life is really exciting.
@if `p20 is 9 then saybar
`%Guy: `0Watch for the oracle!


@#WHORE
;random things that happen walking around the sea hag hotel
@if sexmale is 0 then do
  @begin
  ;if they are female, don't run this... sorry girls, no female version
  ;was written.
  @closescript
  @end
@if `v06 is 1 then do
  @begin
  ;clean mode is on, lets get the hell out of this routine!!
  @closescript
  @end
@busy
@do write
`r1
@clearblock 21 21
@do move 3 21
@do write
`r0  `2A skanky looking woman pulls your arm.  Speak with her? [`0Y`2/`0N`2] :`x
@do readspecial `s01 YN

@if `s01 is N then do
  @begin
  @if `07 < 5 then do
    @begin
    ;person is evil
    @do saybar
You brutally kick her in the face.
    @closescript
    @end
  @do saybar
You push her away.  Poor lost soul.
   @closescript
  @end

@show
`c  `r1`% Close encounters with the whore kind  `r0

`0  "Looking for a good time, sir?  Only `$$25`0." `2she drolls.

`2  Not a bad price, but her clothes are ragged and her face dirty... Would
  it be safe?

@do write
`x`x
@do `v01 is 1
@choice
Why not?  Daddy needs to relax a little bit.
Not today.
@if response is 1 then do
  @begin
  @if money < 25 then do
    @begin
    @show
`\`\  `2You lack the funds for a whore right now.

`k
    @drawmap
    @update
    @closescript
    @end
  @do money - 25
  @do x is 54
  @do y is 12
  @do `p20 is random 5 1
  @if `p20 is 1 then do
    @begin
    ;ha ha, user caught vd
    @do `p12 is 1
    @end
  @show
`\`\  `2She leads you to her bed.

`k`c  `r1  All Aboard  `r0

`2  You remove her garments - as you touch her skin flakes fall off in
  your hand.  You shudder as a finger brushes over a large open sore on her
  back.

`k  It is over quickly.  Your reverie is interrupted by the sound of wretching
  in a corner.  She seems sick.

  `4THERE IS A 20 PERCENT CHANCE THAT YOU JUST CAUGHT SOMETHING.

`k
  @drawmap
  @update
  @do saybar
You put your pants back on.
  @closescript
  @end

@show
`\`\  `$"I do not desire your services right now, woman," `2you inform
  her.

`k
@drawmap
@update

@#inn
;this is for the sea hag hotel
@do `v01 is 1
@offmap
@do moveback
@show
`r0`c  `%`r1  THE SEA HAG HOTEL  `r0

  `2This place looks a little campy - slack jaws sea harlots wander around
  the rooms aimlessly.

  A balding woman with a few teeth missing smiles warmly you at you.

  You are holding `$$&money`2.

@do write
`x`x
@choice
Get a room (`$$50`%)
Leave
@if response is 1 then do
  @begin
  @if money < 50 then do
    @begin
    @show
`\`\`2  You are short on cash.  Pretty sad when you can't even afford to stay
  here...

`k
    @drawmap
    @update
    @closescript
    @end
   @show
`\`\  `2You give the woman the cash.  She leads you inside...
`\`k
  ;has enough money
   @do money - 50
   @do x is 24
   @do y is 4
   @do map is 153
   @loadmap 153
   @drawmap
   @update
   @closescript
  @end

@drawmap
@update

@#heal
@offmap
@do moveback
@do `v01 is 1
@show
`r0`c  `r1  PortTown Healing  `r0

`2  Hoss looks you over for wounds.

@do write
`x`x
@if `p02 < `p03 then do
 @begin
@do `p20 is `p03
@do `p20 - `p02
@do `p20 / 2


 @show
`0"You don't look so good, friend!  I'll fix ya up for `$`p20`0 gold, k?"

@do write
`x`x
@choice
Heal yourself for `$$`p20`%. (you have `$$&money`%)
Limp on out.
@show
`\
@if response is 1 then do begin
 @begin
 @if money < `p20 then do
  @begin
  @show
  `0"Sorry old s&boy, we don't do charity work here."

 @do write
`x`x
 @choice
Well Christ!  How am I supposed to make money when I can barely walk?
Jesus, how 'bout a little compassion for once in your life old man!
How 'bout some of your 'special' pills then?
Yes sir.
@show


@if response is 4 then do
 @begin
 @show
  `0"That's a good lad, now get along with you!" `2 he laughs.

`k
 @end

@if response is 1 then do
 @begin
 @show
  `0"Damn it, s&boy, be a s&man for once in your life!"`2 he yells.

`k
 @end
@if response is 2 then do
 @begin
 @show
  `0"I cannot respect a man who doesn't work," `2Hoss informs you.

`k
 @end
@if response is 3 then do
 @begin
 @do `p02 = 1
 @show
  `0"Sure.  Take uh.. these." `2 he snickers.

  `2You gulp down the weird black pills

  `4HIT POINTS GO DOWN TO 1.

`k
 @end

  @drawmap
  @update
  @closescript
  @end

@do money - `p20
@do `p21 = `p03
@do `p21 - `p02
@do `p02 = `p03
@show
  `2You feel much better as `0`p21`2 hitpoints are restored.

`k
  @end
  @drawmap
  @update
  @closescript
@end

@show
`0"You have no ailments, come back later!" `2Hoss laughs.

`k
@drawmap
@update


@#PIRATE
;The pirate ship
@DO MOVEBACK
@BUSY
@DO `v01 is 1
@SHOW
`r0`c  `r1 Look a Pirate ship!! `r0

  `2The guard yells `0"Arrr, I be a pirate, and you be on me ship.  What do
  you want you land lover?"

@DO WRITE
`x`x
@CHOICE
Ask some pirate trivia
Can I become a pirate?
@IF RESPONSE IS 1 THEN DO
@Begin
@Show
`\`\  `$"What's another name for pirate treasure?"`2 you ask.
`\`k  `0"I believe that'd be booty!!!" `2he replies.
`\`k
@DRAWMAP
@UPDATE
@CLOSESCRIPT
@End
@IF RESPONSE IS 2 THEN DO
@Begin
@Show
`\`\  `0"Arrr, I don't think ye be cool enough to join our drunken
   crew quite yet," `2the scurvy pirate replies.
`\`k
@DRAWMAP
@UPDATE
@CLOSESCRIPT
@End

@#CARGO
;The Cargo ship
@DO MOVEBACK
@BUSY
@DO `v01 is 1
@SHOW
`r0`c  `r1 Looks like a cargo ship `r0

  `2A deckman approaches you `0"We're headed to ArrisVille.  Do you have any
  thing that need to be transported there?"

@DO WRITE
`x`x
@CHOICE
Nope, not really
Stowaway on board
@IF RESPONSE IS 1 THEN DO
@Begin
@Show
`\`\  `$"Nope just taking a look around,"`2 you reply.
`\`k
@DRAWMAP
@UPDATE
@CLOSESCRIPT
@End
@IF RESPONSE IS 2 THEN DO
@Begin
@Show
`\`\  `$"Nothing much," `2you say.  He turns and walks away.  `$"Except for
   myself," `2you laugh as you sneak under deck. (unfinished!!)
`\`k
@DRAWMAP
@UPDATE
@CLOSESCRIPT
@End

@#TRAVEL
;The travel offices
@DO MOVEBACK
@BUSY
@DO `v01 is 1
@SHOW
`r0`c  `r1`% PortTown Travel `r0

  `0"Welcome to PortTown travel, how may I help you?" `2Asks a receptionist.
@DO WRITE
`x`x
@CHOICE
Purchase a world map
Buy a ticket for somewhere
Leave
@IF RESPONSE IS 1 THEN DO
@Begin
@Show
`\`\  `$"I'd like to get a map,"`2 you reply.
`\`k  `0"Okay that'll be 20 gold,"`2 she states.

@if money < 20 then do
        @BEGIN
        @show
  `2You don't have that much, so naturally you take it out on her.

`k  `$"Look you stupid wench, since when do maps cost that much?!?! You just
  lost a customer, lady!" `2you scream.

`k  `2You see tears in her eyes as you storm out the door.
`\`k
        @DRAWMAP
        @UPDATE
        @CLOSESCRIPT
        @End
@show
`2  You plop down the money.`\`\`k
@do money - 20
@do `i20 + 1
@DRAWMAP
@UPDATE
@CLOSESCRIPT
@End

@IF RESPONSE IS 2 THEN DO
@Begin
@Show
`\`\  `$"I need to get out of town," `2you say.  She smiles, `0"Okay where
   would you like to go?" `2You review your choices.

`k
@show
`r0`c                         `r1 `%Porttown Booking Center


@buymanager
26
27
33
@do goto TRAVEL
@End


@IF RESPONSE IS 3 THEN DO
@Begin
@Show
`\`\  `$"Sorry wrong building,"`2 you say as you saunter out the door.
`\`k
@DRAWMAP
@UPDATE
@CLOSESCRIPT
@End

@#MART
;The quicke mart (tm)
@DO MOVEBACK
@BUSY
@DO `v01 is 1
@label martstart
@SHOW
`r0`c  `r1`% Wow, they have everything in here `r0

  `2The clerk behind the counter greets you `0"Oh my golly-gosh, customers!!
  How ever my I help you?"

@DO WRITE
`x`x
@CHOICE
Ask for some beef-jerky
Get a super squishie for 1 gold
Check out five for supplies
Leave
@if responce is 4 then do
 @begin
 @drawmap
 @update
 @closescript
 @end

@IF RESPONSE IS 3 THEN DO
@Begin
@Show
`\`\  `$"I need to get some new gear," `2you say.  He smiles, `0"Okie Doaky
  I hope you enjoy our fine selection of death tools."  `2You review your
  choices.

`k
@show
`r0`c                         `r1 `%Quick-E Mart Stuff


@buymanager
35
36
37
@do goto martstart
@End

@IF RESPONSE IS 1 THEN DO
@Begin
@Show
`\`\  `2You take a look at the jerky, you're pretty sure you're better off
  eating something you killed outside.`%
`\`k
@DO goto martstart
@End
@IF RESPONSE IS 2 THEN DO
@Begin
@if money < 1 then do
  @begin
  @show
`\`\  `0"Are trying to be ripping me off, s&sir?!  You shall not taste a single
  drop of my wonderful liquid!"

`k
  @do goto martstart
  @end
@do money - 1
@Show
`\`\  `$"Give me a super squishie, one that's made entirely out of syrup," `2you
  command.
  `0"An all syrup super squishie?  Oh such a thing has never been done," `2the
  clerk gasps.
`\`k  `$"Just make it happen," `2you say as you lay down the dough.
  `0"Oh dear," `2he moans and turns towards the machine.  It begins to
  rumble, you feel the walls shake.  `0"Oh no, she's breaking up," `2he
  yells....
`\`k  `5DING!
`\`k  `2The clerk turns and hands you your squishie.  `0"All done, if you
  survive, please come again."
`\`k
@DRAWMAP
@UPDATE
@CLOSESCRIPT
@End

@#bank
@do `v01 is 1
@offmap
@do moveback
@label bankstart
@show
`r0`c  `r1 `%2nd Bank Of PortTown `r0

`2  A young clerk eyes you nervously.

@if bank more 0 then do
 @begin
 @show
`2  You are holding `$$&money`2, your account is at `$$&bank`2.

 @end

@if bank is 0 then do
 @begin
 @show
`2  You currently don't have an account with them.

 @end

@do write
`x`x
@choice
>&bank 0 Make a deposit.
>&bank 0 Make a withdraw.
=&bank 0 Apply for an account here.
Leave
@if response is 3 then do
  @begin
  @do `v01 is 1
  @show


  `2The nervous boy asks you to sit down.

  `0"Your full name s&sir?"
  @do `s01 is NIL
  @do write
`x`x
  @do readstring 30 `s01
  @show


  `0"Your current residence?"

  @do write
`x`x
  @do readstring 50 `s01

  @show


  `0"Your net income yearly?"

  @do write
`x`x
  @do readnum 10
  @if `v40 less 20 then do
  @begin
  @show

  @end

  @if `v40 more 19 then do
   @begin
   @show


  `2You giggle to yourself `0-`2 how will they know you just totally lied on
  that last questions?!??  You only made `b19`2 gold pieces last year!
  @end
  @label bankagain
  @show

  `0"How much would you like to open your account with?" `2(you have `$$&money`2)

  @do write
`x`x
  @do readnum 10 money
  @if `v40 is 0 then do
   @begin
   @show


  `2You decide you really don't want to open an account with this
  branch.

`k
  @do goto bankstart
  @end

  @if `v40 > money then do
   @begin
   @show


`2  You don't have this much!  Try again.
   @do goto bankagain
   @end

  @if `v40 < 50 then do
  @begin
  @if money < 50 then do
   @begin
  @show

  `2The clerk eyes your shabby clothing distastefully - as if he knew
  this part was coming.

  `0"I'm sorry s&sir, we do require `$$50 `2to open an account.  And could
  you please leave the pen on your way out." `2he asks haughtily.

`k  `2You carefully return the pen.  `$"I'll be back someday.  And you WILL
  open an account for me then," `2you vow seriously.

  `0"Of course you will, s&sir.  Please exit now, remember, the sign does
  say no loitering.  And this means you." `2he says as he points to the
  door.

`k
@drawmap
@update
@closescript
   @end

  @show


  `0"S&Sir, `$$50 `0is required to open a new account!"
  @do goto bankagain
  @end
  @do money - `v40
  @do bank + `v40
  @show


  `0"Very good S&sir!  Your new account has been opened!"

`k
  @do goto bank
  @end


@if response is 1 then do
  @begin
  @do write
`\
  @label deposit
  @do write
`\  `0"Deposit how much, s&sir?"`\`\`x`x
  @do readnum 10 money
  @if `v40 more money then do
  @begin
  @show
`\`\  `2Maybe you left the money in your other pants?  'cuz it sure ain't here.
  @do goto deposit
  @end
  @if `v40 less 0 then do
  @begin
  @show
`\`\  `2No, this isn't happening and you aren't here.
  @do goto withdraw
  @end

  @do money - `v40
  @do bank + `v40
  @do goto bankstart

  @end

@if response is 2 then do
  @begin
  @do write
`\
  @label withdraw
  @do write
`\  `0"Withdraw how much, s&sir?"`\`\`x`x
  @do `p21 is bank
  @do `p21 - 1
  @if `p21 < 0 then `p21 is 0
  @do readnum 10 `p21
  @if `v40 more bank then do
  @begin
  @show
`\`\  `2You kind of don't have that much in your account.  Nice bookeeping!
  @do goto withdraw
  @end

  @if `v40 less 0 then do
  @begin
  @show
`\`\  `2No, I don't think so.
  @do goto withdraw
  @end

  @if `v40 is bank then do
   @begin
   @show


  `0"But s&sir!  This will close your account with us, are you sure you wish
  to do that?" `2the clerk chokes.

  @do write
`x`x
  @do `v01 is 1
  @choice
Ok, nevermind then.
Yeah.  Get my damn money.
@if response is 1 then goto bank

   @end

  @do money + `v40
  @do bank - `v40
  @do goto bankstart
  @end



@drawmap
@update


@#HANG
;For sitting at the benches for public execution
@DO SAYBAR
`2You'd sit to watch an execution but there isn't one today...

@#NOTDONE
@DO SAYBAR
`2Area unfinished.  Check back when beta ... 6 is ready.
@do moveback

@#FISHDOCK
;Fishing dock...
@do moveback

@if `i28 < 1 then do
  @begin
  ;person doesn't have fishing pole
  @DO SAYBAR
`2You doubt you would catch anything with your s&weapon...
  @closescript
  @end


@if `t10 < 1 then do
  @begin
  @do saybar
You have caught all the fish in the stream.  Maybe tomorrow.
  @closescript
  @end

@busy
@do write
`r1
@clearblock 21 21
@do move 3 21
@do write
`r0  `2Wanna try your luck fishing? [`0Y`2/`0N`2] :`x
@do readspecial `s01 YN

@if `s01 is N then do
  @begin
  @do saybar
Maybe later when the fish are biting.
  @closescript
  @end

@label fishcast

@do `p20 is `i29
@do `p20 + `i30
@do `s01 is `p20
@if `s01 is 0 then `s01 is no

@show
`r0`c  `r1  `%The Fishing Dock  `r0

  `2You sit yourself down on the dock and relax a bit.

  You have `s01 fish.

@do write
`x`x
@do `v01 is 1
@choice
Cast far
Cast short
Get up and leave
@if responce is 3 then do
  @begin
  @drawmap
  @update
  @closescript
  @end

@if response is 1 then do
  @begin
  @do `p20 random 80 20
  @show
`\`\  `2You whip your rod fast and watch as your hook plops down
  about `0`p20`2 feet away.

@end

@if response is 2 then do
  @begin
  @do `p20 random 20 1
  @show
`\`\  `2You gently cast the pole.  Your hook makes a soft splash
  about `0`p20 `2feet away.

@end


@do write
  `2You wait.`l.`l.`l.`l.
@if `t10 < 1 then do
  @begin
  @show
`4No fish are biting.`2

  It looks like the action is finished for today.

`k
  @do goto fishcast
  @end
@do `p20 random 2 1
@if `p20 is 1 then do
   @begin
   @show
`4Nothing happens.

`2  You reel the line back in.

`k
   @do goto fishcast
   @end
@if `p20 is 2 then do
   @begin
   @show
`%You have a bite!`2

@do write
`k
@do `p20 random 4 1
@IF `P20 IS 1 then do
  @begin
  ;catching a special fish
  @show
  The fish is suprisingly strong!  But you reel it in slowly...

@do write
`k
@do `p20 random 4 1
@IF `P20 IS 1 then do
   @begin
   @show
  `bTHE LINE BREAKS!

  `2The mighty fish has escaped.

`k
   @do goto fishcast
   @end
  @show
  `2You have just caught a `0Sparkling Green Salmon`2!
`\`k
  @do `i30 + 1
  @do `t10 - 1
  @do goto fishcast
  @end

  @show
  You slowly reel the fish to shore.

`k  You have caught a Salmon.

`k
   @do `i29 + 1
   @do `t10 - 1
   @do goto fishcast
   @end


  @end



@#WATERFALL
;Looking at the waterfall.
@DO SAYBAR
`2How nice!
@do moveback

@#WATERSIGN
;Sign at the water fall.
@DO SAYBAR
`2To waterfall observation dock.
@do moveback

@#TREES
;At the trees in the passage by the town
@DO SAYBAR
`2A spooky patch of autumn trees

@#shrine
@do `v01 is 1
@do moveback
@busy
@show
`r0`c  `r1`%  THE SHRINE OF BABOS  `r0`\
`2  You kneel in front of the shrine and meditate.`\
@

@if `v04 > 4 then do
  @begin
  @show
`k  Nothing happens.`\`\`k
  @drawmap
  @update
  @closescript
  @end

@if `v04 is 0 then do
  @begin
  @show
`k  Nothing happens.  Maybe if you came on the right day...`\`\`k
  @drawmap
  @update
  @closescript
  @end



@if `t09 is 1 then do
  @begin
  @show
`k  Nothing happens.  You believe there may be limits to even a God's kindness.`\`\`k
  @drawmap
  @update
  @closescript
  @end


;`v04: Lucky Shrine?: 1 = Money, 2, hitpoint, 3, strength 4 defence, else

@if `v04 is 1 then do
  @begin
  @show
`k  `$$500 `0magically appears in your pocket!`\`\`k
  @do money + 500
  @do `t09 is 1
  @end

@if `v04 is 2 then do
  @begin
  @show
`k  `0You feel healthier!  You get two more hitpoints!`\`\`k
  @do `p03 + 2
  @do `p02 + 2
  @do `t09 is 1
  @end

@if `v04 is 3 then do
  @begin
  @show
`k  `%Belar`0 makes you stronger.  You gain one muscle point!`\`\`k
  @do `p04 + 1
  @do `t09 is 1
  @end

@if `v04 is 4 then do
  @begin
  @show
`k  `0You feel the gods protecting you.  You gain one dodge point!`\`\`k
  @do `p05 + 1
  @do `t09 is 1
  @end

  @drawmap
  @update
  @closescript


@#nomore